0x231055a0852d67c7107ad0d0dfeab60278fe6adc

// SPDX-License-Identifier: GPL
pragma solidity ^0.8.13;

import "./Ownable.sol";


contract CeramicAnchorServiceV2 is Ownable {

    //the list of addresses
    mapping (address => bool) allowList;

    //when a service is added to allow list 
    event DidAddCas(address indexed _service);

    //when a service was removed from allow list
    event DidRemoveCas(address indexed _service);

    //upon successful anchor
    event DidAnchor(address indexed _service, bytes32 _root);

    // Only addresses in the allow list is allowed to anchor
    modifier onlyAllowed() {
        require(
            ( allowList[ msg.sender ] || msg.sender == owner() ), 
            "Allow List: caller is not allowed");
        _;
    }

    constructor(){}

    /*
        @name addCas
        @param address _service - the service to be added
        @desc add an address to the allow list
        @note Only owner can add to the allowlist
    */
    function addCas(address _service) public onlyOwner {
        allowList[_service] = true;
        emit DidAddCas(_service);
    }
        
    /*
        @name removeCas
        @param address _service - service to be removed
        @desc Removal can be performed by the owner or the service itself
    */
    function removeCas(address _service) public {
        // require((owner() == _msgSender()) || (allowList[_msgSender()].allowed && _msgSender() == _service), "Caller is not allowed or the owner");
        require((owner() == _msgSender()) || (allowList[_msgSender()] && _msgSender() == _service), "Caller is not allowed or the owner");
        delete allowList[_service];
        emit DidRemoveCas(_service);
    }

    /*
        @name isServiceAllowed
        @param address _service - address to check
        @desc check if a service/address is allowed
    */
    function isServiceAllowed(address _service) public view returns(bool) {
        return allowList[_service];
    }

    /* 
        @name anchor
        @param calldata _root
        @desc Here _root is a byte representation of Merkle root CID.
    */
    function anchorDagCbor(bytes32 _root) public onlyAllowed {
        emit DidAnchor(msg.sender, _root);
    }
    
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}